Calculando e exibindo os números primos entre 2 e 100 - Desafio de Programação Resolvido em Portugol

Numeros primos entre 2 e 100: 
2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71 73 79 83 89 97

programa {
  funcao inicio() {
    // limite dos números primos (incluindo)
    inteiro limite = 100
    logico primo

    // Lembre-se! O número 1 não é primo
    escreva("Numeros primos entre 2 e " + limite + ":\n")
  
    // laço que percorre os valores de 2 até o limite desejado
    para (inteiro i = 2; i <= limite; i++) {
      primo = verdadeiro
                       
      // se o valor de i for 7, a variável j do laço contará
      // de 2 até 7 / 2 (divisão inteira), ou seja, 3. Se o 
      // módulo de 7 por qualquer um dos valores neste intervalo 
      // for igual a 0, então o número não é primo
      para (inteiro j = 2; j <= (i / 2); j++) {
        se (i % j == 0) {
          primo = falso // não é primo
          pare
        }
      }
    
      se (primo == verdadeiro) {
        escreva(i, " ")
      }
    }
  }
}