Escreva um programa Portugol para ler as notas n1 e n2 de um aluno e calcule a sua média aritmética - Exercícios Resolvidos de Portugol

Informe a nota N1: 9.4
Informe a nota N2: 11
Nota inválida. Informe a nota N2: 8.3
A média do aluno é: 8.85
O aluno foi aprovado

Informe a nota N1: 4.2
Informe a nota N2: 1.8
A média do aluno é: 3.0
O aluno reprovou direto.

Informe a nota N1: 5.7
Informe a nota N2: 6
A média do aluno é: 5.85
Informe a nota do exame: 7
A média do aluno com o exame é: 6.425
O aluno foi aprovado após o exame.

// Como calcular a média de um aluno em Portugol
programa {
  funcao inicio() {
    // variáveis usadas na resolução do problema
    real n1, n2, media, exame

    // vamos ler a primeira nota
    escreva("Informe a nota N1: ")
    leia(n1)
    // a nota é válida?
    enquanto ((n1 < 0) ou (n1 > 10)) {
      escreva("Nota inválida. Informe a nota N1: ")
      leia(n1)
    }

    // vamos ler a segunda nota
    escreva("Informe a nota N2: ")  
    leia(n2)
    // a nota é válida?
    enquanto ((n2 < 0) ou (n2 > 10)) {
      escreva("Nota inválida. Informe a nota N2: ")
      leia(n2)
    }

    // vamos calcular a média do aluno
    media = (n1 + n2) / 2.0
    escreva("A média do aluno é: ", media, "\n")

    // o aluno foi aprovado?
    se (media >= 7.0) {
      escreva("O aluno foi aprovado\n")
    }
    // o aluno ficou de exame?
    senao {
      se ((media >= 3.5) e (media < 7.0)) {
        // vamos ler a nota do exame
        escreva("Informe a nota do exame: ")
        leia(exame)
        // a nota é válida?
        enquanto ((exame < 0) ou (exame > 10)) {
          escreva("Nota inválida. Informe a nota do exame: ")
          leia(exame)
        }

        // calcula a nota média
        media = (media + exame) / 2.0
        escreva("A média do aluno com o exame é: ", media, "\n")

        // o aluno foi aprovado após o exame?
        se (media >= 5.0) {
          escreva("O aluno foi aprovado após o exame.\n")
        }
        senao {
          escreva("O aluno foi reprovado após o exame.\n")
        }
      }
      senao {
        escreva("O aluno reprovou direto.\n")
      }
    }
  }
}