Usando o laço enquanto para pedir ao usuário que tente acertar um número aleatório entre 0 e 10 (incluindo) e mostrar a quantidade de tentativas feitas - Exercícios Resolvidos de Portugol

Informe um número de 0 a 10: 5
Errou! Tente um número menor.
Informe um número de 0 a 10: 2
Parabéns! Você acertou em 2 tentativas.

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

programa {
  inclua biblioteca Util --> u
  
  // função principal do programa
  funcao inicio() {
    // declaração das variáveis
    inteiro tentativas = 0, numero_lido
    logico acertou = falso
    // vamos gerar um número aleatório entre 0 e 10
    inteiro numero = u.sorteia(0, 10)
    
    // um laço enquanto que repetirá até que o número seja acertado
    enquanto (acertou != verdadeiro) {
      escreva("Informe um número de 0 a 10: ")
      leia(numero_lido)
      tentativas++
      
      se (numero_lido == numero) { // acertou?
        escreva("Parabéns! Você acertou em " + tentativas + " tentativas.\n")
        acertou = verdadeiro
      }
      senao se (numero_lido < numero) { // o número informado é menor que o número gerado
        escreva("Errou! Tente um número maior.\n")  
      }
      senao { // o número informado é maior que o número gerado
        escreva("Errou! Tente um número menor.\n") 
      }
    }
  }
}