Ler os lados de um triângulo e informar se ele é isósceles, escaleno ou equilátero - Exercícios Resolvidos de Portugol

Informe o primeiro lado do triângulo: 30
Informe o segundo lado do triângulo: 40
Informe o terceiro lado do triângulo: 60
O triângulo é escaleno

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

// Testar o tipo de um triângulo em Portugol
programa {
  funcao inicio() {
    // variáveis usadas na resolução do problema
    inteiro lado_a, lado_b, lado_c

    // vamos ler o primeiro lado do triângulo
    escreva("Informe o primeiro lado do triângulo: ")
    leia(lado_a)

    // vamos ler o segundo lado do triângulo
    escreva("Informe o segundo lado do triângulo: ")
    leia(lado_b)

    // vamos ler o terceiro lado do triângulo
    escreva("Informe o terceiro lado do triângulo: ")
    leia(lado_c)

    // os lados informados formam um triângulo?
    se ((lado_a < (lado_b + lado_c)) e (lado_b < (lado_a + lado_c)) e (lado_c < (lado_a + lado_b))) {
      // é um triângulo equilátero (todos os lados iguais)?
      se ((lado_a == lado_b) e (lado_b == lado_c)) {
        escreva("\nO triângulo é equilátero")
      }
      senao { 
        // é isósceles (dois lados iguais e um diferente)?
        se ((lado_a == lado_b) ou (lado_a == lado_c) ou (lado_c == lado_b)) {
          escreva("\nO triângulo é isósceles")
        }
        senao {
          // é escaleno
          escreva("\nO triângulo é escaleno")
        }
      }
    }
    senao {
      escreva("\nOs lados informados não formam um triângulo.")
    }
  }
}