Como testar se uma matriz é uma Matriz Triangular Superior em Portugol - Desafio de Programação Resolvido em Portugol

Número de linhas e colunas da matriz: 3

Valor para a linha 0 e coluna 0: 8
Valor para a linha 0 e coluna 1: 2
Valor para a linha 0 e coluna 2: 3
Valor para a linha 1 e coluna 0: 0
Valor para a linha 1 e coluna 1: 3
Valor para a linha 1 e coluna 2: 9
Valor para a linha 2 e coluna 0: 0
Valor para a linha 2 e coluna 1: 0
Valor para a linha 2 e coluna 2: 2

Valores na matriz

    8     2     3 
    0     3     9 
    0     0     2 

A matriz é uma matriz triangular superior

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

// Matriz Triangular Superior em Portugol
programa {
  funcao inicio() {
    inteiro ordem
    logico triangular_superior

    // vamos pedir a ordem da matriz
    escreva("Número de linhas e colunas da matriz: ")
    leia(ordem)

    // variáveis usadas na resolução do problema
    // como o VisuAlg não permite a passagem de variáveis
    // na criação do vetor ou matriz, vamos criar uma matriz
    // de no máximo 10 linhas e 10 colunas
    inteiro matriz[ordem][ordem]
    
    // vamos pedir para o usuário informar os valores
    // dos elementos da matriz, uma linha de cada vez
    escreva("\n")
    para (inteiro i = 0; i < ordem; i++) { 
      para (inteiro j = 0; j < ordem; j++) {
        escreva("Linha ", (i + 1), " e coluna ", (j + 1), ": ")
        leia(matriz[i][j])
      }
    }
 
    // vamos mostrar a matriz da forma que ela foi informada
    escreva("\nValores na matriz:\n\n")
    para (inteiro i = 0; i < ordem; i++) {
      para (inteiro j = 0; j < ordem; j++) {
        escreva(matriz[i][j], "   ")
      }
      // passa para a próxima linha da matriz
      escreva("\n")
    }

    // agora vamos testar se a matriz é uma matriz triangular
    // superior
    triangular_superior = verdadeiro

    para (inteiro i = 0; i < ordem; i++) {
      para (inteiro j = 0; j < ordem; j++) {
        // a condição para que a matriz seja triangular superior é
        // que os elementos abaixo da diagonal principal sejam
        // iguais a zero  
        se ((j < i) e (matriz[i][j] != 0)) {
          triangular_superior = falso
        }
      }
    }

    se (triangular_superior == verdadeiro) {
      escreva("\nA matriz é uma matriz triangular superior")
    }
    senao {
      escreva("\nA matriz não é uma matriz triangular superior")
    }
  }
}