Escreva um programa para informar o maior elemento de um vetor de 5 posições do tipo inteiro - Desafio de Programação Resolvido em Portugol

Informe o valor do 1.o elemento: 4
Informe o valor do 2.o elemento: 12
Informe o valor do 3.o elemento: 8
Informe o valor do 4.o elemento: 4
Informe o valor do 5.o elemento: 11
O maior valor no vetor é: 12

// Ler um vetor de 5 inteiros e indicar o maior elemento
programa {
  // função que retorna o maior valor no vetor. Note que o Portugol, ao
  // contrário do VisuAlg, permite a passagem de um vetor ou matriz
  // para uma função.
  funcao maior_valor(inteiro numeros[], inteiro tamanho){
    inteiro maior
    
    // vamos assumir que o maior valor é o primeiro elemento do vetor
    maior = numeros[1]
  	
    // agora vamos varrer o vetor e verificar se existe elemento com
    // um valor maior do que aquele que já temos
    para (inteiro i = 0; i < tamanho; i++){
      se (numeros[i] > maior){
        maior = numeros[i]
      }
    }

    // retorna o maior valor encontrado
    retorne maior
  }
  
  // função principal do programa
  funcao inicio() {
    // vamos declarar e construir um vetor de 5 inteiros
    inteiro numeros[5]
    inteiro maior
 
    // vamos pedir para o usuário informar os valores dos elementos
    para (inteiro i = 0; i < 5; i++){
      escreva("Informe o valor do ", (i + 1), ".o elemento: ")
      leia(numeros[i])
    }

    // agora vamos obter o maior valor
    maior = maior_valor(numeros, 5)
    escreva("O maior valor no vetor é: ", maior)
  }
}