Como testar se dois números são números amigos em Portugol - Escreva um programa Portugol que - Desafio de Programação Resolvido em Portugol

Informe o primeiro número: 220
Informe o segundo número: 284
Os dois números são amigos

Informe o primeiro número: 158
Informe o segundo número: 932
Os números não são amigos.

Informe o primeiro número: 1210
Informe o segundo número: 1184
Os dois números são amigos

// Como testar se dois números são amigos em Portugol

programa {
  funcao inicio() {
    // variáveis usadas na resolução do problema
    inteiro i, n1, n2, soma

    // vamos ler os dois números
    escreva("Informe o primeiro número: ")
    leia(n1)
    escreva("Informe o segundo número: ")
    leia(n2)

    // vamos somar todos os divisores próprios do
    // primeiro número
    soma = 0
    para (inteiro i = 1; i < n1; i++) {
      se (n1 % i == 0) {
        soma = soma + i
      }
    }

    // se essa soma for igual ao valor de n2 nós já temos a
    // primeira condição
    se (soma == n2) {
      // zera a soma  
      soma = 0
      para (inteiro i = 1; i < n2; i++) {
        se (n2 % i == 0) {
          soma = soma + i
        }
      }

      // esta soma é igual ao valor de n1?
      se (soma == n1) {
        escreva("Os dois números são amigos.")
      }
      senao {
        escreva("Os números não são amigos.")
      }
    }
    senao {
      escreva("Os números não são amigos.")
    }
  }
}