Faça um algoritmo que leia a nota de 10 alunos de uma turma e guarde-as em um vetor. No final, mostre - Exercícios Resolvidos de Portugol

Informe a 1.a nota: 9
Informe a 2.a nota: 7.5
Informe a 3.a nota: 8
Informe a 4.a nota: 6.5
Informe a 5.a nota: 9.2
Informe a 6.a nota: 5.7
Informe a 7.a nota: 10
Informe a 8.a nota: 8
Informe a 9.a nota: 9.1
Informe a 10.a nota: 10

Média da turma: 8.3
Quant. alunos acima da média: 5
Maior nota digitada: 10.0

A maior nota aparece na posição: 6
A maior nota aparece na posição: 9

// Vetores e matrizes em Portugol
programa {
  funcao inicio() {
    // variáveis usadas na resolução do problema
    real notas[10]
    real soma, media, maior
    inteiro quant_acima_media
  
    // vamos efetuar a leitura das 10 notas dos alunos
    para (inteiro i = 0; i < 10; i++) {
      escreva("Informe a ", (i + 1), ".a nota: ")
      leia(notas[i])
    }

    // vamos efetuar os cálculos
    maior = notas[0]
    soma = 0.0
    quant_acima_media = 0
    
    para (inteiro i = 0; i < 10; i++) {
      // a nota atual é maior que a nota que temos
      se (notas[i] > maior) {
        maior = notas[i]
      }

      // vamos somar mais esta nota
      soma = soma + notas[i]
    }

    // calcula a média da turma
    media = soma / 10

    // vamos contar os alunos acima da média
    para (inteiro i = 0; i < 10; i++) {
      // esta nota está acima da média?
      se (notas[i] > media) {
        quant_acima_media = quant_acima_media + 1
      }
    }

    // vamos mostrar os dados
    escreva("\nMédia da turma: ", media)
    escreva("\nQuant. alunos acima da média: ", quant_acima_media)
    escreva("\nMaior nota digitada: ", maior)

    // e agora as posições da maior nota
    escreva("\n")
    para (inteiro i = 0; i < 10; i++) {
      se (notas[i] == maior) {
        escreva("\nA maior nota aparece na posição: ", i)
      }
    }
  }
}