Como desenhar uma pirâmide de números em Portugol com números repetindo nas linhas - Desafio de Programação Resolvido em Portugol

Informe a quantidade de linhas da pirâmide: 6

      1 
     2 2 
    3 3 3 
   4 4 4 4 
  5 5 5 5 5 
 6 6 6 6 6 6

// Um programa Portugol que desenha uma pirâmide de números
programa {
  // função principal do programa
  funcao inicio() {
    // precisamos de um contador de linhas da pirâmida
    inteiro quant_linhas, contador_linhas = 1
 
    // vamos ler a quantidade de linhas da pirâmide
    escreva("Informe a quantidade de linhas da pirâmide: ")
    leia(quant_linhas) 
    
    // um laço PARA que começa na quantidade de linhas informada
    // pelo usuário e reduz até 0
    escreva("\n")
    para (inteiro i = quant_linhas; i > 0; i--) {
      // imprimimos i espaços no início de cada linha
      para (inteiro j = 1; j <= i; j++) {
        escreva(" ")
      }
 
      // agora imprimimos o valor do contador de linhas da pirâmide
      // no final de cada linha
      para (inteiro j = 1; j <= contador_linhas; j++) {
        escreva(contador_linhas, " ")
      }
 
      // pulamos para a próxima linha
      escreva("\n")
 
      // e aumentamos o contador de linhas
      contador_linhas = contador_linhas + 1
    }
  }
}