Como contar as vogais em uma palavra, frase ou texto em Portugol - Desafio de Programação Resolvido em Portugol

Informe uma palavra, frase ou texto: Gosto de Portugol
A palavra ou frase contém 6 vogais 

// Como contar as vogais em uma palavra, frase ou texto

programa {
  // vamos importar a biblioteca Texto 
  inclua biblioteca Texto --> tx
  
  funcao inicio() {
    // Variáveis usadas na resolução do problema
    cadeia frase
    caracter c
    inteiro quant_vogais

    // primeiro nós inicializamos o contador de vogais
    // com o valor 0
    quant_vogais = 0
  
    // agora nós pedimos para o usuário informar uma palavra,
    // frase ou texto
    escreva("Informe uma palavra, frase ou texto: ")
    leia(frase)
  
    // para facilitar, vamos converter todo a string para letras
    // minúsculas
    frase = tx.caixa_baixa(frase)

    // vamos usar um laço PARA para percorrer todas os
    // caracteres da palavra, frase ou texto
    para (inteiro i = 0; i <= tx.numero_caracteres(frase) - 1; i++) {
      // obtemos o caractere atual
      c = tx.obter_caracter(frase, i)
      // este caractere é uma vogal?
      se ((c == "a") ou (c == "e") ou (c == "i") ou (c == "o") ou (c == "u")) {
        quant_vogais = quant_vogais + 1
      }
    }

    // mostramos o resultado
    escreva("A palavra ou frase contém ", quant_vogais, " vogais")
  }
}