Usando apenas vetores, escreva um programa Portugol que leia o nome de cinco alunos e as três notas de cada um. Em seguida - Desafio de Programação Resolvido em Portugol

Nome do 1.o aluno: OSMAR SILVA
Nota N1 do aluno OSMAR SILVA: 9.5
Nota N2 do aluno OSMAR SILVA: 10
Nota N3 do aluno OSMAR SILVA: 7.3

Nome do 2.o aluno: FERNANDA GOMES
Nota N1 do aluno FERNANDA GOMES: 8
Nota N2 do aluno FERNANDA GOMES: 9.2
Nota N3 do aluno FERNANDA GOMES: 6.9

Nome do 3.o aluno: CARLOS SOUZA
Nota N1 do aluno CARLOS SOUZA: 9.4
Nota N2 do aluno CARLOS SOUZA: 10
Nota N3 do aluno CARLOS SOUZA: 7.1

Nome do 4.o aluno: LUIZ PEREIRA
Nota N1 do aluno LUIZ PEREIRA: 8.3
Nota N2 do aluno LUIZ PEREIRA: 9.8
Nota N3 do aluno LUIZ PEREIRA: 10

Nome do 5.o aluno: MARIA SANTOS
Nota N1 do aluno MARIA SANTOS: 8.7
Nota N2 do aluno MARIA SANTOS: 10
Nota N3 do aluno MARIA SANTOS: 9.8

ALUNOS E SUAS MÉDIAS:

Aluno: OSMAR SILVA
Média: 8,93

Aluno: FERNANDA GOMES
Média: 8,03

Aluno: CARLOS SOUZA
Média: 8,83

Aluno: LUIZ PEREIRA
Média: 9,37

Aluno: MARIA SANTOS
Média: 9,50

Média da turma: 8,93
Quant. alunos acima da média: 2

// Nomes, notas e médias de alunos em Portugol
programa {
  funcao inicio() {
    // vetor de nomes de alunos
    cadeia nomes[5]
    // 3 vetores para as três notas de cada aluno
    real notas1[5]
    real notas2[5]
    real notas3[5]
    // um vetor para guardar as médias
    real medias[5]
    // soma das médias
    real soma_medias, media_turma
    // quantidade de alunos acima da média
    inteiro quant_acima_media
  
    // inicializa as variáveis necessárias
    quant_acima_media = 0
    soma_medias = 0.0

    // vamos ler os nomes dos alunos e suas notas
    para (inteiro i = 0; i < 5; i++) {
      escreva("Nome do ", (i + 1), ".o aluno: ")  
      leia(nomes[i])
      escreva("Nota N1 do aluno ", nomes[i], ": ")
      leia(notas1[i])
      escreva("Nota N2 do aluno ", nomes[i], ": ")
      leia(notas2[i])
      escreva("Nota N3 do aluno ", nomes[i], ": ")
      leia(notas3[i])

      // agora vamos calcular a média desse aluno
      medias[i] = (notas1[i] + notas2[i] + notas3[i]) / 3.0

      // somamos mais essa média
      soma_medias = soma_medias + medias[i]

      escreva("\n")
    }

    // saíamos do laço. Hora de calcular a média da turma
    media_turma = soma_medias / 5.0

    // mostramos os dados dos alunos
    escreva("ALUNOS E SUAS MÉDIAS:\n")
    para (inteiro i = 0; i < 5; i++) {
      escreva("Aluno: ", nomes[i], "\n")
      escreva("Média: ", medias[i], "\n")
      escreva("\n")
    }

    // vamos mostrar a média da turma
    escreva("Média da turma: ", media_turma)

    // vamos calcular a quantidade de alunos com média
    // acima da média da turma
    para (inteiro i = 0; i < 5; i++) {
      se (medias[i] > media_turma) {
        quant_acima_media = quant_acima_media + 1
      }
    }

    // e mostramos a quantidade de alunos acima da média
    escreva("\nQuant. alunos acima da média: ", quant_acima_media)
  }
}