Como testar se um número informado pertence a série Fibonacci - Desafio de Programação Resolvido em Portugol

Informe um número: 21
Pertence à sequência Fibonacci

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

programa {
  // função principal do programa
  funcao inicio() {
    // variáveis usadas na resolução do problema
    inteiro numero
   
    // vamos solicitar um número inteiro positivo
    escreva("Informe um número: ")
    // lê o número
    leia(numero)
     
    // vamos testar se o número pertence à sequência
    // Fibonacci
    se (pertenceSerieFibonacci(numero)) {
      escreva("Pertence à sequência Fibonacci")
    }
    senao {
      escreva("Não pertence à sequência Fibonacci")
    }
  }

  // função que recebe um número e informa se ele pertence
  // à sequência Fibonacci
  funcao logico pertenceSerieFibonacci(inteiro n) {
    // define os termos iniciais
    inteiro primeiro = 0, segundo = 1, terceiro = 0
    
    // enquanto o terceiro valor for menor que o número informado
    enquanto (terceiro < n) {
      terceiro = primeiro + segundo
      primeiro = segundo
      segundo = terceiro
    }
         
    // pertence à sequência Fibonacci?    
    se (terceiro == n) {
      retorne verdadeiro
    }
    senao {
      retorne falso
    }
  }
}