Como inverter a ordem dos elementos de um array usando apenas uma variável temporária - Desafio de Programação Resolvido em Portugol

// declara, constrói e inicializa um array de 10 inteiros
inteiro valores[] = {6, 3, 90, 1, 54, 7, 12, 32, 9, 4}
inteiro temp

Ordem inicial:

6   3   90   1   54   7   12   32   9   4   

Ordem invertida:

4   9   32   12   7   54   1   90   3   6

// Como inverter um vetor em Portugol
programa {
  funcao inicio() {
    // declara, constrói e inicializa um array de 10 inteiros
    inteiro valores[] = {6, 3, 90, 1, 54, 7, 12, 32, 9, 4}
    inteiro tamanho, temp, inicial, final

    // guarda o tamanho do vetor
    tamanho = 10

    // vamos mostar a ordem inicial dos elementos no vetor
    escreva("Ordem inicial:\n\n")
    para (inteiro i = 0; i < tamanho; i++) {
      escreva(valores[i], "   ")
    }

    // vamos inverter a ordem dos elementos no array
    inicial = 0
    final = tamanho - 1
    enquanto (inicial < final) {
      temp = valores[inicial]
      valores[inicial] = valores[final]
      valores[final] = temp
      // incrementa e decrementa as variáveis de controle
      inicial++
      final--
    }

    // mostra o vetor na ordem invertida
    escreva("\n\nOrdem invertida:\n\n")
    para (inteiro i = 0; i < tamanho; i++) {
      escreva(valores[i], "   ")
    }  
  }
}