Escreva um programa Portugol que pede ao usuário dois números inteiros e mostre a soma dos números entre eles, sem incluí-los - Desafio de Programação Resolvido em Portugol

Informe o primeiro número: 5
Informe o segundo número: 9
A soma é: 21

Informe o primeiro número: 9
Informe o segundo número: 5
A soma é: 21

Informe o primeiro número: 9
Informe o segundo número: 9
A soma é: 0

// Como somar os números em um intervalo de inteiros
programa {
  funcao inicio() {
    // variáveis usadas na resolução do problema
    inteiro num1, num2, menor, maior, soma

    // vamos iniciar a soma como zero
    soma = 0

    // vamos pedir os dois números inteiros
    escreva("Informe o primeiro número: ")
    leia(num1)
    escreva("Informe o segundo número: ")
    leia(num2)

    // faz a validação dos valores
    se (num2 > num1) {
      menor = num1
      maior = num2
    }
    senao {
      maior = num1
      menor = num2
    }

    // agora fazemos a soma dos números entre o número
    // menor e o maior informados pelo usuário
    para (inteiro i = (menor + 1); i < maior; i++) {
      soma = soma + i
    }

    // mostramos o resultado
    escreva("A soma é: ", soma)
  }
}