Como calcular o seno, co-seno, tangente, secante, co-secante e co-tangente de um ângulo informado pelo usuário - Desafio de Programação Resolvido em Portugol

Informe o ângulo em graus: 35
O ângulo em graus informado foi: 35.0
O ângulo em radianos é: 0.6108652381980153
O seno do ângulo é: 0.573576436351046
O cosseno do ângulo é: 0.8191520442889918
A tangente do ângulo é: 0.7002075382097097
A co-tangente do ângulo é: 1.4281480067421146
A secante do ângulo é: 1.220774588761456
A co-secante do ângulo é: 1.7434467956210982

// Calcular seno, cosseno e tangente em Portugol

programa {
  // Inclui a biblioteca Matemática
  inclua biblioteca Matematica --> mat

  funcao inicio() {
    // variáveis usadas na resolução do problema
    real angulo_graus, angulo_radianos, seno, co_seno
    real tangente, co_tangente, secante, co_secante

    // vamos pedir para o usuário informar um ângulo em graus
    escreva("Informe o ângulo em graus: ")
    leia(angulo_graus)
    escreva("O ângulo em graus informado foi: ", angulo_graus)

    // vamos converter o ângulo em graus para ângulo em radianos
    angulo_radianos = angulo_graus * (mat.PI / 180.0)
    escreva("\nO ângulo em radianos é: ", angulo_radianos)

    // vamos calcular o seno do ângulo
    seno = mat.seno(angulo_radianos)
    // vamos calcular o cosseno do ângulo
    co_seno = mat.cosseno(angulo_radianos)
    // vamos calcular a tangente do ângulo
    tangente = mat.tangente(angulo_radianos)
    // vamos calcular a co-tangente do ângulo
    co_tangente = (1.0 / tangente)
    // vamos calcular a secante do ângulo
    secante = (1.0 / co_seno)
    // vamos calcular a co-secante do ângulo
    co_secante = (1.0 / seno)

    // e mostramos os resultados
    escreva("\nO seno do ângulo é: ", seno)
    escreva("\nO cosseno do ângulo é: ", co_seno)
    escreva("\nA tangente do ângulo é: ", tangente)
    escreva("\nA co-tangente do ângulo é: ", co_tangente)
    escreva("\nA secante do ângulo é: ", secante)
    escreva("\nA co-secante do ângulo é: ", co_secante)
  }
}