Como remover os espaços no início de uma palavra, frase ou texto em Portugol

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

programa {
  // vamos incluir a biblioteca Texto
  inclua biblioteca Texto --> texto
  
  funcao inicio() {
    caracter caractere // para obter caracteres individuais
    inteiro contador // contador de caracteres
    
    // vamos declarar uma variável para receber uma
    // frase com espaços no início e no fim
    cadeia frase = "   Tenho espaços no início e no fim   "

    // vamos mostrar a frase original
    escreva("A frase original com espaços antes e depois é: #")
    escreva(frase + "#")

    // vamos remover os espaços apenas no início
    contador = 0 // vamos ajustar para o primeiro caractere
    // obtemos o primeiro caractere da frase
    caractere = texto.obter_caracter(frase, 0)
    // é um caractere de espaço
    enquanto (caractere == " ") {
      // aumentamos o contador
      contador++
      // e passamos para o próximo caractere
      caractere = texto.obter_caracter(frase, contador)
    }

    // agora que já sabemos a quantidade de caracteres no início
    // da frase, só precisamos usar a função extrair_subtexto() para
    // obter apenas o trecho da frase após os espaços iniciais
    frase = texto.extrair_subtexto(frase, contador,
      texto.numero_caracteres(frase))
    // vamos mostrar a frase com os espaços removidos no início
    escreva("\nA frase sem espaços no início: #")
    escreva(frase + "#")
  }
}