Faça um programa que sorteie um número aleatório entre 0 e 500 e pergunte ao usuário qual é o "número mágico". O programa deverá - Desafio de Programação Resolvido em Portugol

Adivinhe o número mágico: 100
Tente um número menor.

Adivinhe o número mágico: 50
Tente um número maior.

Adivinhe o número mágico: 60
Tente um número maior.

Adivinhe o número mágico: 80
Tente um número maior.

Adivinhe o número mágico: 90
Tente um número maior.

Adivinhe o número mágico: 95
Tente um número menor.

Adivinhe o número mágico: 94
Tente um número menor.

Adivinhe o número mágico: 93
Tente um número menor.

Adivinhe o número mágico: 92
Você acertou o número em 9 tentativas.
Classificação: Normal

// Desafio do número mágico em Portugol
programa {
  inclua biblioteca Util --> u
  
  funcao inicio() {
    // variáveis usadas na resolução do problema
    inteiro numero_magico, palpite, tentativas
    logico acertou

    // inicializa as variáveis
    tentativas = 0
    acertou = falso

    // vamos sortear o número entre 0 e 500
    numero_magico = u.sorteia(0, 500)

    // um laço que repete enquanto o usuário não
    // acertar o número mágico
    enquanto (nao acertou) {
      escreva("Adivinhe o número mágico: ")
      leia(palpite)

      // registra essa tentativa
      tentativas = tentativas + 1

      // o usuário acertou o número mágico?
      se (palpite == numero_magico) {
        escreva("Você acertou o número em ", tentativas, " tentativas.\n")

        // mostra a classificação do usuário
        se (tentativas <= 3) {
          escreva("Classificação: Muito Sortudo\n")
        }
        senao {
          se ((tentativas >= 4) e (tentativas <= 6)) {
            escreva("Classificação: Sortudo\n")
          }
          senao {
            se ((tentativas >= 7) e (tentativas <= 10)) {
              escreva("Classificação: Normal\n")
            }
            senao {
              escreva("Classificação: Tente Novamente\n")
            }
          }
        }

        // sai do laço
        acertou = verdadeiro
      }
      senao {
        // indica se o palpite é maior ou menor
        se (palpite < numero_magico) {
          escreva("Tente um número maior.\n\n")
        }
        senao {
          escreva("Tente um número menor.\n\n")
        }
      }
    }
  }
}