Como testar se dois números são números amigos em VisuAlg - Escreva um programa VisuAlg que - Exercícios Resolvidos de VisuAlg

Informe o primeiro número: 220
Informe o segundo número: 284
Os dois números são amigos

Informe o primeiro número: 158
Informe o segundo número: 932
Os números não são amigos.

Informe o primeiro número: 1210
Informe o segundo número: 1184
Os dois números são amigos

algoritmo "Como testar se dois números são amigos em VisuAlg"

var
  // variáveis usadas na resolução do problema
  i, n1, n2, soma: inteiro

inicio
  // vamos ler os dois números
  escreva("Informe o primeiro número: ")
  leia(n1)
  escreva("Informe o segundo número: ")
  leia(n2)

  // vamos somar todos os divisores próprios do
  // primeiro número
  soma <- 0
  para i de 1 ate (n1 - 1) faca
    se n1 mod i = 0 entao
      soma <- soma + i
    fimse
  fimpara

  // se essa soma for igual ao valor de n2 nós já temos a
  // primeira condição
  se soma = n2 entao
    // zera a soma
    soma <- 0
    para i de 1 ate (n2 - 1) faca
      se n2 mod i = 0 entao
        soma <- soma + i
      fimse
    fimpara

    // esta soma é igual ao valor de n1?
    se soma = n1 entao
      escreva("Os dois números são amigos.")
    senao
      escreva("Os números não são amigos.")
    fimse
  senao
    escreva("Os números não são amigos.")
  fimse

fimalgoritmo