Elabore um programa VisuAlg que efetue a leitura sucessiva de valores numéricos e apresente no final o somatório, a média e o total de valores lidos - Desafio de Programação Resolvido em VisuAlg

Informe o valor (negativo para parar): 8
Informe o valor (negativo para parar): 3
Informe o valor (negativo para parar): 5
Informe o valor (negativo para parar): 1
Informe o valor (negativo para parar): -3

A soma dos números é: 17
O total de números lidos é: 4
A média dos números é: 4.25

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Leitura sucessiva de valores numéricos em VisuAlg"

var
  // variáveis usadas na resolução do problema
  numero, soma, total_numeros: inteiro
  media: real

inicio
  soma <- 0
  total_numeros <- 0

  // vamos efetuar a leitura dos números
  repita
    escreva("Informe o valor (negativo para parar): ")
    leia(numero)

    // o número é positivo?
    se numero >= 0 entao
      // vamos somar mais este número
      soma <- soma + numero
      // vamos contar mais este número
      total_numeros <- total_numeros + 1
    fimse
  ate numero < 0

  // vamos calcular a média dos números lidos
  se total_numeros > 0 entao
    media <- soma / (total_numeros * 1.0)

    escreval()
    escreval("A soma dos números é: ", soma)
    escreval("O total de números lidos é: ", total_numeros)
    escreval("A média dos números é: ", media)
  senao
    escreval()
    escreval("Não foram informados números positivos.")
  fimse

fimalgoritmo