Fazer um programa para receber um número inteiro de segundos do usuário e imprimir a quantidade correspondente em horas - Exercícios Resolvidos de VisuAlg

Informe a quantidade de segundos: 10350
Resultado: 02:52:30

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Converter segundos em horas, minutos e segundos"

var
  // variáveis que vão guardar o resultado em horas,
  // minutos e segundos;
  horas, minutos, segundos: inteiro
  quant_segundos: inteiro // guardará os segundos informados

// função usada para formatar as horas, minutos e
// segundos
funcao formatar_numero(n: inteiro): caractere
inicio
  se n < 10 entao
    retorne "0" + Numpcarac(n)
  senao
    retorne Numpcarac(n)
  fimse
fimfuncao

inicio
  // vamos pedir para o usuário informar a quantidade
  // de segundos
  escreva("Informe a quantidade de segundos: ")

  // vamos ler os segundos informados
  leia(quant_segundos)

  // vamos obter a quantidade de horas
  horas <- Int(quant_segundos / 3600)
  // vamos obter os minutos
  minutos <- (Int(quant_segundos / 60)) mod 60
  // vamos obter os segundos restantes
  segundos <- quant_segundos mod 60

  // vamos exibir o resultado em horas, minutos e segundos
  escreva("Resultado: ", formatar_numero(horas), ":")
  escreva(formatar_numero(minutos), ":", formatar_numero(segundos))

fimalgoritmo