Faça um algoritmo que leia a nota de 10 alunos de uma turma e guarde-as em um vetor. No final, mostre - Desafio de Programação Resolvido em VisuAlg

Informe a 1.a nota: 9
Informe a 2.a nota: 7.5
Informe a 3.a nota: 8
Informe a 4.a nota: 6.5
Informe a 5.a nota: 9.2
Informe a 6.a nota: 5.7
Informe a 7.a nota: 10
Informe a 8.a nota: 8
Informe a 9.a nota: 9.1
Informe a 10.a nota: 10

Média da turma: 8.3
Quant. alunos acima da média: 5
Maior nota digitada: 10.0

A maior nota aparece na posição: 6
A maior nota aparece na posição: 9

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Uso de vetores e matrizes em VisuAlg"

var
  // variáveis usadas na resolução do problema
  notas: vetor[0..9] de real
  soma, media, maior: real
  quant_acima_media, i: inteiro
  
inicio
  // vamos efetuar a leitura das 10 notas dos alunos
  para i de 0 ate 9 faca
    escreva("Informe a ", (i + 1), ".a nota: ")
    leia(notas[i])
  fimpara

  // vamos efetuar os cálculos
  maior <- notas[0]
  soma <- 0.0
  quant_acima_media <- 0
  para i de 0 ate 9 faca
    // a nota atual é maior que a nota que temos
    se notas[i] > maior entao
      maior <- notas[i]
    fimse

    // vamos somar mais esta nota
    soma <- soma + notas[i]
  fimpara

  // calcula a média da turma
  media <- soma / 10

  // vamos contar os alunos acima da média
  para i de 0 ate 9 faca
    // esta nota está acima da média?
    se notas[i] > media entao
      quant_acima_media <- quant_acima_media + 1
    fimse
  fimpara

  // vamos mostrar os dados
  escreval()
  escreval("Média da turma: ", media)
  escreval("Quant. alunos acima da média: ", quant_acima_media)
  escreval("Maior nota digitada: ", maior)

  // e agora as posições da maior nota
  escreval()
  para i de 0 ate 9 faca
    se notas[i] = maior entao
      escreval("A maior nota aparece na posição: ", i)
    fimse
  fimpara

fimalgoritmo