 |
|
|
|
Você está aqui: VisuAlg ::: Desafios e Lista de Exercícios Resolvidos ::: Arrays e Matrix (Vetores e Matrizes) |
Matriz Simétrica em VisuAlg - Um programa VisuAlg que testa se uma matriz quadrada é uma matriz simétrica - Exercícios Resolvidos de VisuAlgQuantidade de visualizações: 658 vezes |
|
Pergunta/Tarefa: Antes de fazermos a resolução deste exercício de matrizes em VisuAlg, é importante revermos alguns conceitos sobre a matriz simétrica. O que é uma matriz simétrica Uma matriz simétrica é toda matriz cuja matriz transposta é igual à própria matriz, ou seja, A = At. Para compreender o que é uma matriz simétrica, é importante revermos o que é uma matriz transposta. Matriz transposta: quando invertemos as linhas e colunas de uma matriz, ou seja, dada a matriz A, a matriz transposta de A, representada por At, terá em sua primeira coluna a primeira linha da matriz A; já a segunda coluna da matriz transposta será a segunda linha da matriz A, e assim sucessivamente. Veja a figura:  Matriz simétrica: sabendo o que é uma matriz transposta, dada a matriz A, quando calculamos a matriz transposta de A e encontramos a própria matriz A, ou seja, A = At, então essa matriz é simétrica. Escreva um programa VisuAlg que declara uma matriz de inteiros de 3 linhas e 3 colunas e peça para o usuário informar os valores de cada elemento. Em seguida mostre a matriz informada e indique se a matriz é uma matriz simétrica ou não. Sua saída deverá ser parecida com: Elemento na linha 1 e coluna 1: 5 Elemento na linha 1 e coluna 2: 1 Elemento na linha 1 e coluna 3: 2 Elemento na linha 2 e coluna 1: 1 Elemento na linha 2 e coluna 2: 6 Elemento na linha 2 e coluna 3: 3 Elemento na linha 3 e coluna 1: 2 Elemento na linha 3 e coluna 2: 3 Elemento na linha 3 e coluna 3: 8 5 1 2 1 6 3 2 3 8 A matriz informada é uma matriz simétrica. Veja a resolução comentada deste exercício em VisuAlg: ----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------
algoritmo "Matriz simétrica em VisuAlg"
var
// variáveis usadas na resolução do problema
matriz: vetor[1..3, 1..3] de inteiro
i, j, n: inteiro
simetrica: logico
inicio
n <- 3 // ordem da matriz quadrada
simetrica <- verdadeiro
// vamos pedir para o usuário informar os valores
// dos elementos da matriz, uma linha de cada vez
para i de 1 ate n faca
para j de 1 ate n faca
escreva("Linha", i, "e coluna", j, ": ")
leia(matriz[i, j])
fimpara
fimpara
// agora verificamos se a matriz é simétrica
para i de 1 ate n faca
se simetrica = falso entao
interrompa
fimse
para j de 1 ate n faca
se simetrica = falso entao
interrompa
fimse
// os elementos em posicoes simetricas sao iguais?
se matriz[i, j] <> matriz[j, i] entao
simetrica <- falso
fimse
fimpara
fimpara
// vamos mostrar a matriz da forma que ela foi informada
escreval()
escreval("Valores na matriz:")
escreval()
para i de 1 ate n faca
para j de 1 ate n faca
escreva(matriz[i, j]:5, " ")
fimpara
// passa para a próxima linha da matriz
escreval()
fimpara
escreval()
se simetrica = verdadeiro entao
escreval("A matriz informada é uma matriz simétrica.")
senao
escreval("A matriz informada não é uma matriz simétrica.")
fimse
fimalgoritmo
|
 Link para compartilhar na Internet ou com seus amigos: |
Mais Desafios de Programação e Exercícios e Algoritmos Resolvidos de VisuAlg |
Veja mais Dicas e truques de VisuAlg |
Dicas e truques de outras linguagens |
E-Books em PDF |
||||
|
||||
|
||||
Linguagens Mais Populares |
||||
|
1º lugar: Java |
