Uma função VisuAlg que recebe um valor inteiro e informa se o mesmo é um número primo - Exercícios Resolvidos de VisuAlg

funcao primo(valor: inteiro): logico
inicio
  // implementação aqui
fimfuncao

Informe um valor inteiro: 7
O numero informado é primo

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Uma função VisuAlg para informar se um número é primo"

var
  // variáveis usadas na resolução do problema
  numero: inteiro

// função que retorna verdadeiro se o número fornecido
// como argumento for primo
funcao primo(valor: inteiro): logico
var
  i: inteiro
  numero_primo: logico
inicio
  numero_primo <- verdadeiro

  // se o valor fornecido for 7, a variável i do laço contará
  // de 2 até 7 / 2 (divisão inteira), ou seja, 3. Se o
  // módulo de 7 por qualquer um dos valores neste intervalo
  // for igual a 0, então o número não é primo
  para i de 2 ate Int(valor / 2) faca
    se valor mod i = 0 entao
      numero_primo <- falso // não é primo
      interrompa
    fimse
  fimpara

  retorne numero_primo
fimfuncao

inicio
  // vamos pedir para o usuário informar um número inteiro
  escreva("Informe um valor inteiro: ")
  leia(numero)

  // vamos verificar se o valor informado é um número primo
  se primo(numero) = verdadeiro entao
    escreva("O numero informado é primo.")
  senao
    escreva("O numero informado NÃO é primo.")
  fimse

fimalgoritmo