Como converter decimal em binário em VisuAlg usando o laço ENQUANTO - Exercícios Resolvidos de VisuAlg

Informe um número decimal: 38
A representação binária é 100110

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Como converter de decimal para binário em VisuAlg"

var
  // variáveis usadas na resolução do problema
  decimal, decimal_temp, temp: inteiro
  binario: caractere

inicio
  // vamos ler o número decimal
  escreva("Informe um número decimal: ")
  leia(decimal)
  decimal_temp <- decimal // para mostrar o resultado no final
  binario <- "" // vai guardar o resultado

  // laço while repetirá enquanto decimal for maior ou igual a 2
  enquanto decimal >= 2 faca
    temp <- decimal % 2
    binario <- Numpcarac(temp) + binario
    decimal <- Int(decimal / 2)
  fimenquanto

  binario <- Numpcarac(decimal) + binario // insere o dígito 1 restante
  escreva("A representação binária é ", binario)

fimalgoritmo