Escreva um programa VisuAlg que leia os elementos de um vetor A de dez elementos inteiros e construa outro vetor B - Lista de Exercícios Resolvidos de VisuAlg

Informe o valor do 1.o elemento: 8
Informe o valor do 2.o elemento: 5
Informe o valor do 3.o elemento: 4
Informe o valor do 4.o elemento: 1
Informe o valor do 5.o elemento: 2
Informe o valor do 6.o elemento: 3
Informe o valor do 7.o elemento: 4
Informe o valor do 8.o elemento: 6
Informe o valor do 9.o elemento: 9
Informe o valor do 10.o elemento: 7

Elementos do vetor A:

8,  5,  4,  1,  2,  3,  4,  6,  9,  7  

Elementos do vetor B:

24,  10,  12,  2,  6,  6,  12,  12,  27,  14

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Combinando dois vetores em VisuAlg"

var
  // vamos declarar e construir dois vetores de 10 inteiros
  vetor_a: vetor[0..9] de inteiro
  vetor_b: vetor[0..9] de inteiro
  i: inteiro

inicio
  // agora vamos pedir para o usuário informar os valores
  // dos elementos do vetor A
  para i de 0 ate 9 faca
    escreva("Valor do", (i + 1), ".o elemento: ")
    leia(vetor_a[i])
  fimpara

  // vamos construir o vetor B
  para i de 0 ate 9 faca
    // o índice atual é par?
    se i mod 2 = 0 entao
      vetor_b[i] <- vetor_a[i] * 3
    senao
      vetor_b[i] <- vetor_a[i] * 2
    fimse
  fimpara

  // vamos mostrar os elementos do vetor A
  escreval()
  escreval("Elementos do vetor A:")
  escreval()
  para i de 0 ate 9 faca
    escreva(vetor_a[i], ",  ")
  fimpara

  // vamos mostrar os elementos do vetor B
  escreval()
  escreval("Elementos do vetor B:")
  escreval()
  para i de 0 ate 9 faca
    escreva(vetor_b[i], ",  ")
  fimpara

fimalgoritmo