Escreva um programa VisuAlg que pede ao usuário dois números inteiros e mostre a soma dos números entre eles, sem incluí-los - Lista de Exercícios Resolvidos de VisuAlg

Informe o primeiro número: 5
Informe o segundo número: 9
A soma é: 21

Informe o primeiro número: 9
Informe o segundo número: 5
A soma é: 21

Informe o primeiro número: 9
Informe o segundo número: 9
A soma é: 0

algoritmo "Como somar os números em um intervalo de inteiros"

var
  // variáveis usadas na resolução do problema
  i, num1, num2, menor, maior, soma: inteiro

inicio
  // vamos iniciar a soma como zero
  soma <- 0

  // vamos pedir os dois números inteiros
  escreva("Informe o primeiro número: ")
  leia(num1)
  escreva("Informe o segundo número: ")
  leia(num2)

  // faz a validação dos valores
  se num2 > num1 entao
    menor <- num1
    maior <- num2
  senao
    maior <- num1
    menor <- num2
  fimse

  // agora fazemos a soma dos números entre o número
  // menor e o maior informados pelo usuário
  para i de (menor + 1) ate (maior - 1) faca
    soma <- soma + i
  fimpara

  // mostramos o resultado
  escreva("A soma é: ", soma)

fimalgoritmo