Leia um vetor de 10 posições e verifique se existem valores iguais (repetidos) e os escreva - Exercícios Resolvidos de VisuAlg

Informe o 1.o valor: 6
Informe o 2.o valor: 2
Informe o 3.o valor: 4
Informe o 4.o valor: 6
Informe o 5.o valor: 1
Informe o 6.o valor: 1
Informe o 7.o valor: 8
Informe o 8.o valor: 5
Informe o 9.o valor: 4
Informe o 10.o valor: 7

Os números repetidos foram: 6,  4,  1

Informe o 1.o valor: 8
Informe o 2.o valor: 7
Informe o 3.o valor: 6
Informe o 4.o valor: 1
Informe o 5.o valor: 2
Informe o 6.o valor: 3
Informe o 7.o valor: 50
Informe o 8.o valor: 32
Informe o 9.o valor: 4
Informe o 10.o valor: 11

Não houve números repetidos

algoritmo "Leia um vetor de 10 posições e verifique"

// Enunciado do exercício: Leia um vetor de 10 posições e verifique
// se existem valores iguais (repetidos) e os escreva. Se não houver
// números duplicados, mostre uma mensagem informando.

var
  // variáveis usadas na resolução do problema
  numeros: vetor[1..10] de inteiro
  repetidos: vetor[1..10] de inteiro
  i, j, aux, contador: inteiro
  registrado: logico
inicio
  // vamos fazer a leitura dos 10 números inteiros
  para i de 1 ate 10 faca
    escreva("Informe o", i, ".o valor: ")
    leia(numeros[i])
  fimpara

  // agora vamos verificar os valores repetidos no vetor
  // numeros e guardá-los no vetor repetidos
  contador <- 0
  para i de 1 ate 10 faca
    para j de i ate 10 faca
      // vamos comparar os valores nos diferentes índices
      // do vetor numeros
      se ((numeros[i] = numeros[j]) e (i <> j)) entao
        // encontramos uma repetição. Vamos verificar se ela
        // já foi registrada
        registrado <- falso
        para aux de 1 ate contador faca
          se repetidos[aux] = numeros[i] entao
            registrado <- verdadeiro
            interrompa
          fimse
        fimpara
        
        // essa repetição não foi registrada ainda
        se registrado = falso entao
          contador <- contador + 1
          repetidos[contador] <- numeros[i]
        fimse
        
      fimse
    fimpara
  fimpara
  
  // vamos mostrar os valores repetidos
  se contador = 0 entao
    escreval()
    escreval("Não houve números repetidos")
  senao
    escreval()
    escreva("Os números repetidos foram:")
    para i de 1 ate contador faca
      escreva(repetidos[i], ", ")
    fimpara
  fimse
fimalgoritmo