Calculando e exibindo os números primos entre 2 e 100 - Exercícios Resolvidos de VisuAlg

Numeros primos entre 2 e 100: 
2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71 73 79 83 89 97

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Números primos de 2 até 100"

var
  // limite dos números primos (incluindo)
  limite: inteiro
  primo: logico
  i, j: inteiro

inicio
  limite <- 100

  // Lembre-se! O número 1 não é primo
  escreval("Numeros primos entre 2 e ", limite, ":")

  // laço que percorre os valores de 2 até o limite desejado
  para i de 2 ate limite faca
    primo <- verdadeiro

    // se o valor de i for 7, a variável j do laço contará
    // de 2 até 7 / 2 (divisão inteira), ou seja, 3. Se o
    // módulo de 7 por qualquer um dos valores neste intervalo
    // for igual a 0, então o número não é primo
    para j de 2 ate Int(i / 2) faca
      se (i % j = 0) entao
        primo <- falso // não é primo
        interrompa
      fimse
    fimpara

    se (primo = verdadeiro) entao
      escreva(i, " ")
    fimse
  fimpara

fimalgoritmo