Como converter de octal para decimal em VisuAlg usando um laço ENQUANTO

algoritmo "Algoritmo para converter de octal para decimal"

var
  octal, decimal: inteiro

// função que recebe um número octal e converte para decimal
funcao octal_para_decimal(octal: inteiro): inteiro
var
  dec, i: inteiro
inicio
  dec <- 0 // inicializamos dec em 0
  i <- 0 // esta variável representará a potência de 8

  // enquanto octal for maior que 0
  enquanto octal > 0 faca
    dec <- dec + int((octal mod 10) * (Exp(8, i)))
    // dividimos octal por 10 (divisão por inteiros)
    octal <- int(octal / 10)
    // incrementamos a potência
    i <- i + 1
  fimenquanto

  // retornamos o decimal
  retorne dec
fimfuncao

inicio
  // vamos pedir um número octal
  escreva("Informe um número octal: ")
  leia(octal)

  // mostramos o octal informado
  escreval("O otctal informado foi: ", octal)

  // agora convertemos de octal para decimal
  decimal <- octal_para_decimal(octal)

  // mostramos o resultado
  escreva("O número decimal é: ", decimal)

fimalgoritmo