Como testar se uma matriz é uma Matriz Triangular Superior em VisuAlg - Exercícios Resolvidos de VisuAlg

Número de linhas e colunas da matriz: 3

Valor para a linha 0 e coluna 0: 8
Valor para a linha 0 e coluna 1: 2
Valor para a linha 0 e coluna 2: 3
Valor para a linha 1 e coluna 0: 0
Valor para a linha 1 e coluna 1: 3
Valor para a linha 1 e coluna 2: 9
Valor para a linha 2 e coluna 0: 0
Valor para a linha 2 e coluna 1: 0
Valor para a linha 2 e coluna 2: 2

Valores na matriz

    8     2     3 
    0     3     9 
    0     0     2 

A matriz é uma matriz triangular superior

algoritmo "Matriz Triangular Superior em VisuAlg"

var
  // variáveis usadas na resolução do problema
  // como o VisuAlg não permite a passagem de variáveis
  // na criação do vetor ou matriz, vamos criar uma matriz
  // de no máximo 10 linhas e 10 colunas
  matriz:vetor[1..10, 1..10] de inteiro
  ordem, i,j: inteiro
  triangular_superior: logico

inicio
  // vamos pedir a ordem da matriz
  escreva("Número de linhas e colunas da matriz: ")
  leia(ordem)

  // vamos pedir para o usuário informar os valores
  // dos elementos da matriz, uma linha de cada vez
  escreval()
  para i de 1 ate ordem faca
    para j de 1 ate ordem faca
      escreva("Linha", i, "e coluna", j, ": ")
      leia(matriz[i, j])
    fimpara
  fimpara

  // vamos mostrar a matriz da forma que ela foi informada
  escreval()
  escreval("Valores na matriz:")
  escreval()
  para i de 1 ate ordem faca
    para j de 1 ate ordem faca
      escreva(matriz[i, j]:5, " ")
    fimpara
    // passa para a próxima linha da matriz
    escreval()
  fimpara

  // agora vamos testar se a matriz é uma matriz triangular
  // superior
  triangular_superior <- verdadeiro

  para i de 1 ate ordem faca
    para j de 1 ate ordem faca
      // a condição para que a matriz seja triangular superior é
      // que os elementos abaixo da diagonal principal sejam
      // iguais a zero
      se ((j < i) e (matriz[i, j] <> 0)) entao
        triangular_superior <- falso
      fimse
    fimpara
  fimpara

  escreval()
  se triangular_superior = verdadeiro entao
    escreval("A matriz é uma matriz triangular superior")
  senao
    escreva("A matriz não é uma matriz triangular superior")
  fimse

fimalgoritmo