Um algoritmo VisuAlg que calcula qual o menor número possível de notas de 100, 50, 10, 5 e 1 em que o valor a ser sacado pode ser decomposto - Desafio de Programação Resolvido em VisuAlg

Informe o valor do saque (valor inteiro): 139
O valor do saque pode ser expresso em:
1 notas de 100
0 notas de 50
3 notas de 10
1 notas de 5
4 notas de 1

algoritmo "Quantidade mínima de notas em um caixa eletrônico"

var
  // variáveis usadas na resolução do problema
  cem, cinquenta, dez, cinco, um: inteiro
  valor, temp: inteiro
inicio
  // variáveis que vão guardar a quantidade de notas de 100, 50, 10, 5 e 1;
  cem <- 0
  cinquenta <- 0
  dez <- 0
  cinco <- 0
  um <- 0

  // vamos solicitar o valor a ser sacado
  escreva("Informe o valor do saque (valor inteiro): ")
  // vamos ler o valor do saque
  leia(valor)

  // inicializa a variável temporária
  temp <- valor

  // quantas notas de 100?
  se temp >= 100 entao
    cem <- Int(valor / 100)
    temp <- valor % 100
  fimse
  
  // quantas notas de 50?
  se temp >= 50 entao
    cinquenta <- Int(temp / 50)
    temp <- temp % 50
  fimse
  
  // quantas notas de 10?
  se temp >= 10 entao
    dez <- Int(temp / 10)
    temp <- temp % 10
  fimse
    
  // quantas notas de 5?
  se temp >= 5 entao
    cinco <- Int(temp / 5)
    temp <- temp % 5
  fimse
  
  // quantas notas de 1?
  se temp >= 1 entao
    um <- Int(temp / 1)
  fimse

  // vamos exibir o resultado
  escreval("O valor do saque pode ser expresso em:")
  escreval(cem, " notas de 100")
  escreval(cinquenta, " notas de 50")
  escreval(dez, " notas de 10")
  escreval(cinco, " notas de 5")
  escreval(um, " notas de 1")

fimalgoritmo