Faça um algoritmo que preencha um vetor de 30 posições com números entre 1 e 15 sorteados pelo computador. Depois disso, peça para o usuário - Exercícios Resolvidos de VisuAlg

Digite um número a ser localizado: 8

O número 8 aparece nas seguintes posições:

[8] posição => 5
[8] posição => 22
[8] posição => 26

O número 8 apareceu => 3 vez(es).

algoritmo "Preencher um vetor com números aleatórios em VisuAlg"

var
  // variáveis usadas na resolução do problema
  numeros: vetor[1..30] de inteiro
  i, chave, vezes: inteiro

// função principal do programa
inicio
  vezes <- 0

  // vamos sortear 30 números de 1 até 15 (incluindo os dois)
  para i de 1 ate 30 faca
    numeros[i] <- RandI(15) + 1
  fimpara

  // vamos pedir para o usuário informar a chave e vamos verificar em
  // quais posições essa chave foi encontrada
  escreva("Digite um número a ser localizado: ")
  leia(chave)

  escreval() 		
  escreval("O número", chave, " aparece nas seguintes posições:")
  escreval()
		
  para i de 1 ate 30 faca
    se (numeros[i] = chave) entao
      // registra a quantidade de vezes
      vezes <- vezes + 1
      escreval("[", numeros[i], "]", " posição => ", i)
    fimse
  fimpara

  // agora mostramos quantas vezes o número pesquisado apareceu
  escreval()
  escreval("O número", chave, " apareceu => ", vezes, " vez(es).")
  escreval()

fimalgoritmo