Ler um número de três dígitos, separá-lo e invertê-lo, escrevendo o número lido e sua forma inversa - Exercícios Resolvidos de VisuAlg

Informe um valor inteiro de três dígitos: 753
O valor original é: 753
O valor invertido é: 357

algoritmo "Algoritmo"
var
  // variáveis usadas na resolução do problema
  numero, temp, inverso: inteiro

inicio
  // vamos solicitar ao usuário que informe um valor inteiro
  // na faixa 100 a 999 (incluindo)
  escreva("Informe um valor inteiro de três dígitos: ")
  // vamos ler o valor informado
  leia(numero)

  // vamos verificar se o valor está na faixa permitida
  se ((numero < 100) ou (numero > 999)) entao
    escreva("Valor fora da faixa permitida")
  senao
    // vamos criar uma variável temporária para
    // manter intacto o valor lido
    temp <- numero
    inverso <- 0 // guardará o valor invertido

    // vamos inverter o valor agora
    enquanto temp <> 0 faca
      inverso <- (inverso * 10) + (temp % 10)
      temp <- Int(temp / 10)
    fimenquanto

    // vamos mostrar o resultado
    escreval("O valor original é: ", numero)
    escreval("O valor invertido é: ", inverso)
  fimse

fimalgoritmo