Como remover os espaços no final de uma palavra, frase ou texto em Portugol

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

programa {
  // vamos incluir a biblioteca Texto
  inclua biblioteca Texto --> texto
  
  funcao inicio() {
    caracter caractere // para obter caracteres individuais
    inteiro contador // contador de caracteres
    
    // vamos declarar uma variável para receber uma
    // frase com espaços no início e no fim
    cadeia frase = "   Tenho espaços no início e no fim    "

    // vamos mostrar a frase original
    escreva("A frase original com espaços antes e depois é: #")
    escreva(frase + "#")

    // vamos remover os espaços apenas no final
    // vamos ajustar para o último caractere
    contador = texto.numero_caracteres(frase) - 1
    // obtemos o último caractere da frase
    caractere = texto.obter_caracter(frase, contador)
    // é um caractere de espaço
    enquanto (caractere == " ") {
      // diminuimos o contador
      contador--
      // e passamos para o caractere anterior ao atual
      caractere = texto.obter_caracter(frase, contador)
    }

    // agora que já sabemos a quantidade de caracteres de espaço no final
    // da frase, só precisamos usar a função extrair_subtexto() para
    // obter apenas o trecho da frase antes dos espaços finais
    frase = texto.extrair_subtexto(frase, 0, contador + 1)
    // vamos mostrar a frase com os espaços removidos no final
    escreva("\nA frase sem espaços no final: #")
    escreva(frase + "#")
  }
}